SqlServer: 如何更改表的文件组？(进而改变存储位置)

USE [master]
GO
IF EXISTS(SELECT 1 FROM sys.databases AS d WHERE d.name='dbTest')
	DROP DATABASE dbTest
GO
CREATE DATABASE [dbTest]
 ON  PRIMARY
(
    NAME = N'dbTest',
    FILENAME = N'c:\dbTest.mdf',
    SIZE = 8192KB,
    FILEGROWTH = 65536KB
)
 LOG ON 
(
    NAME = N'dbTest_log',
    FILENAME = N'c:\dbTest_log.ldf',
    SIZE = 8192KB,
    FILEGROWTH = 65536KB
)
GO
USE dbTest
GO
CREATE TABLE A(id INT ,CONSTRAINT PK_A PRIMARY KEY(id))
CREATE TABLE B(id INT ,CONSTRAINT PK_B PRIMARY KEY(id))
CREATE TABLE C(id INT ,CONSTRAINT PK_C PRIMARY KEY(id))
GO
----- 以上为测试库及测试表 --------

--1. 加文件组
USE [master]
GO
ALTER DATABASE [dbTest] ADD FILEGROUP [tableB]
GO
--2. 加文件到文件组
USE [master]
GO
ALTER DATABASE [dbTest] ADD FILE ( NAME = N'tableB', FILENAME = N'D:\tableB.ndf' , SIZE = 8192KB , FILEGROWTH = 65536KB ) TO FILEGROUP [tableB]
GO
--3. 修改表的文件组
USE dbTest
GO
--3.1 去除原来的主键约束
ALTER TABLE B DROP CONSTRAINT PK_B
GO
--3.2 添加主键约束，而且指定文件组
ALTER TABLE B ADD CONSTRAINT PK_B PRIMARY KEY (id) ON tableB;
GO

操作完毕， 表名上右键 ，查看属性，在存储那里可以清楚看到：文件组已改为 tableB